나는 코드를 만들려고 노력했지만 아래에서 설명한대로 G9
값 을 일치시키는 방법을 완성 할 수 없습니다 ColE:E
.
Excel 파일에는 이름 Sheet1
과 Sheet4
. Sheet1
데이터가 있고 해당 데이터는 Sheet4
값을 일치 시킨 후 붙여 넣습니다 .
Sheet4.Range ( "G9") = 코드는 해당 값을 Sheet1.Range ( "E : E") =에 일치시킵니다.
코드가 일치하면 노란색으로 강조 표시된 데이터를 열 끝까지 복사하고 전치하여 Sheet4.range ( "G11")에 붙여 넣습니다.
어떤 도움이라도 대단히 감사하겠습니다.
내 코드
Sub myfunc()
Dim Cell As Range
With Sheet1
For Each Cell In .Range("E1:E" & .Cells(.Rows.Count, "E").End(xlUp).Row)
If Cell.Value = Sheet4.Range("G9") Then
'looking for method
End If
Next Cell
End With
End Sub
코드
Option Explicit
Sub myCopyTranspose()
' Define constants.
Const sFirstCell As String = "E7"
Const sCopyFirstColumn As String = "D"
Const dCriteriaCell As String = "G9"
Const dFirstCell As String = "G11"
' Define Source Search (Column) Range and Row Offset.
Dim rg As Range
Dim cel As Range
Dim RowOffset As Long
With Sheet1.Range(sFirstCell)
Set cel = .Resize(.Worksheet.Rows.Count - .Row + 1) _
.Find("*", , xlFormulas, , , xlPrevious)
If cel Is Nothing Then Exit Sub ' no data
Set rg = .Resize(cel.Row - .Row + 1)
RowOffset = .Row - 1
End With
' Retrieve Criteria.
Dim cValue As Variant: cValue = Sheet4.Range(dCriteriaCell).Value
If IsError(cValue) Then Exit Sub ' error value
If Len(cValue) = 0 Then Exit Sub ' empty or blank
cValue = CStr(cValue)
' Find a match of Criteria in Source Search Range.
Dim cMatch As Variant
cMatch = Application.Match("*" & cValue & "*", rg, 0)
If IsError(cMatch) Then Exit Sub ' no match
' Define Source Copy (Row) Range.
With Sheet1.Cells(cMatch + RowOffset, sCopyFirstColumn)
Set cel = Nothing
Set cel = .Resize(, .Worksheet.Columns.Count - .Column + 1) _
.Find("*", , xlFormulas, , , xlPrevious)
If cel Is Nothing Then Exit Sub ' no data
Set rg = .Resize(, cel.Column - .Column + 1)
End With
' Copy/Transpose Source Copy (Row) Range to Destination (Column) Range.
Application.ScreenUpdating = False
rg.Copy
Sheet4.Range(dFirstCell).PasteSpecial _
Paste:=xlPasteAll, _
Transpose:=True
Application.CutCopyMode = False
Application.ScreenUpdating = True
' Inform user.
MsgBox "Data transferred.", vbInformation, "Success"
End Sub
이 기사는 인터넷에서 수집됩니다. 재 인쇄 할 때 출처를 알려주십시오.
침해가 발생한 경우 연락 주시기 바랍니다[email protected] 삭제
몇 마디 만하겠습니다