gnuplot脚本错误“无效表达式”

debugcn 发表于 Dev

用户名

以下是用于输出gif文件的连续图像的代码：

for i in {1..600}
do
python Phy_asg.py $i
gnuplot <<- EOF
    unset tics;unset key;unset border
    set xrange [-15:15]
    set yrange [-15:15]
    set arrow 1 from 0.012*$i,cos(0.012*$i)-pi to sin(0.024*$i),cos(0.012*$i ) nohead ls 8 lw 2
    set arrow 2 from sin(0.024*$i)+pi,0.012*$i to sin(0.024*$i),cos(0.012*$i ) nohead ls 8 lw 2
    plot "< seq -9 .2 -3.1" u (cos(2*$1)):($1) with lines
    replot "< seq -9 .2 -3.1" u ($1):(cos(2*$1)) with lines
    replot "data_asg.txt" with lines lt 22 lw 2
    set terminal png size 512,512
    set output "Phy_gif_$i.png"
    replot
EOF
done

这里Phy_asg.py是Python脚本，用于以文本文件的形式生成数据，名称为data_asg.txt。外壳在第10行给我错误。它说：

gnuplot> plot "< seq -9 .2 -3.1" u (cos(2*)):() with lines
                                      ^
     line 0: invalid expression

我无法解决问题。是seq命令还是格式错误。

克里斯多夫

该$1被解释为壳参数代替的数据列。要么逃脱美元，\$1要么使用column(1)，我更喜欢后者

for i in {1..600}
do
python Phy_asg.py $i
gnuplot <<- EOF
    set terminal png size 512,512
    set output "Phy_gif_$i.png"
    unset tics;unset key;unset border
    set xrange [-15:15]
    set yrange [-15:15]
    set arrow 1 from 0.012*$i,cos(0.012*$i)-pi to  sin(0.024*$i),cos(0.012*$i ) nohead ls 8 lw 2
    set arrow 2 from sin(0.024*$i)+pi,0.012*$i to sin(0.024*$i),cos(0.012*$i ) nohead ls 8 lw 2
    set style data lines
    plot "< seq -9 .2 -3.1" u (cos(2*column(1) )):1, \
         "< seq -9 .2 -3.1" u 1:(cos(2*column(1))), \
         "data_asg.txt" lt 22 lw 2
EOF
done

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。